BITTE helfen Sie uns HEUTE mit einer SPENDE
Helfen Sie das OpenOffice Forum zu erhalten!

DANKE >><< DANKE

> KEINE WERBUNG FÜR REGISTRIERTE BENUTZER!<
Ihre Spende wird für die Deckung der laufenden Kosten sowie den Erhalt und Ausbau 🌱 des OpenOffice Forums verwendet.
🤗 Als Dankeschön werden Sie im Forum als OO-SUPPORTER gekennzeichnet. 🤗

Rechenoperationen abhängig von der Anzahl an Einträgen

CALC ist die Tabellenkalkulation, die Sie immer wollten.
huldrych
Beiträge: 8
Registriert: So 3. Nov 2019, 11:04

Rechenoperationen abhängig von der Anzahl an Einträgen

Beitrag von huldrych » So 3. Nov 2019, 11:16

Guten Morgen allerseits!
Mit der Kalkulationsfunktion habe ich einige Erfahrung, bin aber leider nicht ausreichend versiert, um das folgende Problem zu lösen. Darum wende ich mich an diese Community und bitte um Hilfe.
Es geht um ein Kalkulation mit ca. 15 Spalten.
Wie die Einträge in den Spalten 4-15 verrechnet werden hängt davon ab, wieviele Einträge sich den Spalten 1-3 befinden, oder konkret formuliert:
- 0 Einträge in Spalten C,D,E
- 1 Eintrag in Spalten C,D,E (egal in welcher Spalte)
- 2 Einträge in Spalten C,D,E (egal in welcher Spalte)
- 3 Einträge in Spalten C,D,E
Es geht nicht darum, was jeweils in den Spalten 1-3 steht, sondern ob da was steht und in wie vielen von den drei Spalten.
Dementsprechend gibt es vier unterschiedliche "Ausgänge" die jeweils zu einer anderen Gewichtung in der Verrechnung der Zahlenwerte in den folgenden Spalten führen.
Für Hinweise bin ich sehr dankbar.
Beste Grüße!

Kalk
Beiträge: 482
Registriert: Do 6. Feb 2014, 19:45

Re: Rechenoperationen abhängig von der Anzahl an Einträgen

Beitrag von Kalk » So 3. Nov 2019, 11:28

Hallo,

das einfachste wäre eine Wenn() Kombination.
Es kommt darauf an, wie es weiter verarbeitet wird für andere Lösungen.

Code: Alles auswählen

=WENN(ANZAHL2(C4:E20)=0;"Wertung 0";WENN(ANZAHL2(C4:E20)=1;"Wertung 1";WENN(ANZAHL2(C4:E20)=2;"Wertung 2";WENN(ANZAHL2(C4:E20)=3;"Wertung 3";""))))
Gruß Kalk
Gruß Kalk

huldrych
Beiträge: 8
Registriert: So 3. Nov 2019, 11:04

Re: Rechenoperationen abhängig von der Anzahl an Einträgen

Beitrag von huldrych » So 3. Nov 2019, 11:32

Vielen Dank, "Kalk"!
Das probiere ich nachher gleich aus.
Einen schönen Sonntag noch.

mikele
Beiträge: 771
Registriert: Sa 23. Jul 2011, 22:09

Re: Rechenoperationen abhängig von der Anzahl an Einträgen

Beitrag von mikele » So 3. Nov 2019, 11:52

Hallo,
oder auch

Code: Alles auswählen

=WAHL(ANZAHL2(C1:E1)+1;"Wertung 0";"Wertung 1";"Wertung 2";"Wertung 3")
Gruß,
mikele

huldrych
Beiträge: 8
Registriert: So 3. Nov 2019, 11:04

Re: Rechenoperationen abhängig von der Anzahl an Einträgen

Beitrag von huldrych » So 3. Nov 2019, 13:56

Also, ich habe den Hinweis von "Kalk" folgendermaßen umgesetzt:

WENN(ANZAHL2(C7:F7)=0;J7*0,4+MITTELWERT(M7:S7)*0,6;
WENN(ANZAHL2(C7:F7)=1;MITTELWERT(C7:F7)*0,1+J7*0,4+MITTELWERT(M7:S7)*0,5;
WENN(ANZAHL2(C7:F7)=2;MITTELWERT(C7:F7)*0,16+J7*0,4+MITTELWERT(M7:S7)*0,44;
WENN(ANZAHL2(C7:F7)=3;MITTELWERT(C7:F7)*0,2+J7*0,4+MITTELWERT(M7:S7)*0,4)

Vielen Dank. Das funktioniert tadellos, allerdings erst, wenn in den "Blöcken" C7-F7 und M7-S7 unf im Feld J7 jeweils mindestens ein Zahlenwert steht, ansonsten wird "#DIV/0!" angezeigt.

Da es sich um ein häufig anzuwendendes Tabellendokument handelt, ist die Anzeige "#DIV/0!" auf Dauer etwas unschön. Welche Operation muss ich einfügen, damit das Ergebnisfeld leer bleibt (oder "0" anzeigt oder ein nettes Icon), bis ausreichend Einträge vorhanden sind, um ein Ergebnis anzuzeigen?

Wiederum bin ich für einen Hinweis sehr sehr dankbar.

Mondblatt24
Beiträge: 812
Registriert: Do 9. Mär 2017, 09:53

Re: Rechenoperationen abhängig von der Anzahl an Einträgen

Beitrag von Mondblatt24 » So 3. Nov 2019, 17:03

Hallo,
Da es sich um ein häufig anzuwendendes Tabellendokument handelt, ist die Anzeige "#DIV/0!" auf Dauer etwas unschön. Welche Operation muss ich einfügen, damit das Ergebnisfeld leer bleibt (oder "0" anzeigt oder ein nettes Icon), bis ausreichend Einträge vorhanden sind, um ein Ergebnis anzuzeigen?

Wiederum bin ich für einen Hinweis sehr sehr dankbar.
z.B. so: =WENN(ISTFEHLER(WENN(ANZAHL2(C7:F7)=0;J7*0,4+MITTELWERT(M7:S7)*0,6;WENN(ANZAHL2(C7:F7)=1;MITTELWERT(C7:F7)*0,1+J7*0,4+MITTELWERT(M7:S7)*0,5;WENN(ANZAHL2(C7:F7)=2;MITTELWERT(C7:F7)*0,16+J7*0,4+MITTELWERT(M7:S7)*0,44;WENN(ANZAHL2(C7:F7)=3;MITTELWERT(C7:F7)*0,2+J7*0,4+MITTELWERT(M7:S7)*0,4)))));"";WENN(ANZAHL2(C7:F7)=0;J7*0,4+MITTELWERT(M7:S7)*0,6;WENN(ANZAHL2(C7:F7)=1;MITTELWERT(C7:F7)*0,1+J7*0,4+MITTELWERT(M7:S7)*0,5;WENN(ANZAHL2(C7:F7)=2;MITTELWERT(C7:F7)*0,16+J7*0,4+MITTELWERT(M7:S7)*0,44;WENN(ANZAHL2(C7:F7)=3;MITTELWERT(C7:F7)*0,2+J7*0,4+MITTELWERT(M7:S7)*0,4)))))

Gruß Peter
Zuletzt geändert von Mondblatt24 am So 3. Nov 2019, 19:20, insgesamt 1-mal geändert.
Win 11 (x64) ▪ 24.2.2.2 (x64) ▪ AOO Portable 4.1.15
Wenn Eure Frage zutreffend beantwortet wurde, seid so nett und fügt dem Betreff der Eingangsfrage [GELÖST] hinzu.

huldrych
Beiträge: 8
Registriert: So 3. Nov 2019, 11:04

Re: Rechenoperationen abhängig von der Anzahl an Einträgen

Beitrag von huldrych » So 3. Nov 2019, 18:06

Vielen Dank, Peter, auch für deine Nachricht.
Wenn ich allerdings die vorgeschlagene verschachtelte WENN-Funktion in das entsprechende Feld kopiere, wird nichts angezeigt: weder wenn zu wenig Werte eingetragen sind (dann soll ja nichts erscheinen) noch wenn ausreichend Werte eingetragen sind.
Leider schaffe ich es nicht die Syntax so zu verändern, dass es funktioniert.
Any help in sight?

Kalk
Beiträge: 482
Registriert: Do 6. Feb 2014, 19:45

Re: Rechenoperationen abhängig von der Anzahl an Einträgen

Beitrag von Kalk » So 3. Nov 2019, 18:30

Hallo,

so sollte es funktionieren.

Code: Alles auswählen

=WENN(ISTFEHLER((MITTELWERT(C7:F7))+(MITTELWERT(M7:S7)));"";WENN(ANZAHL2(C7:F7)=0;J7*0,4+MITTELWERT(M7:S7)*0,6;WENN(ANZAHL2(C7:F7)=1;MITTELWERT(C7:F7)*0,1+J7*0,4+MITTELWERT(M7:S7)*0,5;WENN(ANZAHL2(C7:F7)=2;MITTELWERT(C7:F7)*0,16+J7*0,4+MITTELWERT(M7:S7)*0,44;WENN(ANZAHL2(C7:F7)=3;MITTELWERT(C7:F7)*0,2+J7*0,4+MITTELWERT(M7:S7)*0,4)))))
bzw.

Code: Alles auswählen

=WENN(ISTFEHLER((MITTELWERT(C7:F7))+(MITTELWERT(M7:S7)));"";WAHL(ANZAHL2(C7:E7)+1;J7*0,4+MITTELWERT(M7:S7)*0,6;MITTELWERT(C7:F7)*0,1+J7*0,4+MITTELWERT(M7:S7)*0,5;MITTELWERT(C7:F7)*0,16+J7*0,4+MITTELWERT(M7:S7)*0,44;MITTELWERT(C7:F7)*0,2+J7*0,4+MITTELWERT(M7:S7)*0,4))
Gruß Kalk
Gruß Kalk

balu
Beiträge: 155
Registriert: Di 12. Okt 2010, 11:35

Re: Rechenoperationen abhängig von der Anzahl an Einträgen

Beitrag von balu » So 3. Nov 2019, 19:16

Hallo,

@Kalk
Du hast eine Bedingung vrgessen, und zwar ob J7 einen Eintrag beinhaltet.
Dein zweiter Lösungsvorschlag ist aber dafür besser :) . Es fehlt jedoch J7.


Also, jetzt auch noch ich ;-)

Als erstes tausche ich =ANZAHL2() gegen =ANZAHL(). Denn das erste zählt auch Text mit, wobei das zweite nur Werte zählt. Dieser Unterschied kann helfen Probleme zu umgehen.

Und als nächstes setzte ich eine andere Überptüfung ein, ob mindestens ein Wert pro Datenbereich, beziehungsweise einem Datenfeld vorhanden ist. Das ganze sieht dann so aus.

Code: Alles auswählen

(ANZAHL(C7:F7)>=1)*(ISTZAHL(J7)*(ANZAHL(M7:S7)>=1)
Und nun verschmelze ich das ganze mit dem zweiten Lösungsvorschlag von Kalk, und heraus kommt dann das hier.

Code: Alles auswählen

=WENN((ANZAHL(C7:F7)>=1)*(ISTZAHL(J7)*(ANZAHL(M7:S7)>=1);WAHL(ANZAHL(C7:E7)+1;J7*0,4+MITTELWERT(M7:S7)*0,6;MITTELWERT(C7:F7)*0,1+J7*0,4+MITTELWERT(M7:S7)*0,5;MITTELWERT(C7:F7)*0,16+J7*0,4+MITTELWERT(M7:S7)*0,44;MITTELWERT(C7:F7)*0,2+J7*0,4+MITTELWERT(M7:S7)*0,4);"")
Wenn jetzt also die Überprüfung WAHR ergibt, wird WAHL ausgeführt, ansonsten wird eine leere Zelle ausgegeben "" (am ende der Formel).



Gruß
balu

huldrych
Beiträge: 8
Registriert: So 3. Nov 2019, 11:04

Re: Rechenoperationen abhängig von der Anzahl an Einträgen

Beitrag von huldrych » So 3. Nov 2019, 19:55

Vielen Dank euch allen, die ihr mitgeholfen habt, mein Problem zu lösen.
Dankeschön!

Antworten